*
*  Script to draw lines, which sets vrange and create a legend automatically
*
*  Written MC, LSCE, Mars 2000, Modified CBAR_LINE script
*  Modify by B.-J. Tsuang, NCHU, Nov 2005
*
function lineplot (args)
*
nusage=41
usage.0 ='lineplot: draw lines, which sets vrange and creates a legend automatically'
usage.1='    lineplot -x X -y Y -h 0|1 -p -s 0|1|2 -v v1 v2 ... vn -l "l1" "l2" ... "ln"'
usage.2=''
usage.3='  parameters: '
usage.4='     -x X       x position of the lenend center on graph (in) (default at the center of the graph)'
usage.5='     -y Y       y position on graph (in) (default at the bottom of the graph)'
usage.6='     -h 0|1     1: draw legend horizontally (default); 0: vertically.'
usage.7='     -p         if set, user can click on graphic to place legend.'
usage.8='     -s 0|1|2   0: GrADS default symbol (white_line green_line yellow_line ..)'
usage.9='                1: (symbol white_line green_line ...)(default)'
usage.10='               2: (white_line green_line red_line ...)'
usage.11='     -v v1 v2 ... vn   variables for line plot, the variables can be any'
usage.12='                grads vaild variable without "-", including define variables'
usage.13='     -l "l1" "l2" ... "ln"   legend for each variables, must be double, e.g., "ERA40" "NCEP2"'
usage.14='  Use lineplot without parameters to get a short discription.'
usage.15='  Function call and switches can be uppercase and lowercase.'
usage.16='  Defaults are 0 and no text.'
usage.17='  If one keyword misses a value, lineplot uses the default for the remaining values.'
usage.18=''
usage.19=' Example calls of lineplot:'
usage.20=''
usage.21='    set time jan1980 dec2000'
usage.22='    set x 1'
usage.23='    set y 1'
usage.24='    define diff=p.1-slp.2'
usage.25='    lineplot -v p.1 slp.2 diff -l "ERA40" "NCEP2" "ERA40-NCEP2" -s 2'
usage.26='    lineplot -v ta.3 ta.1 ta.2 -l "obs" "ERA40" "NCEP2" -s 1'
usage.27='    lineplot -v t(lev=1000) t(lev=850) t(lev=700) -l "1000 hPa" "850 hPa" "700 hPa" -s 2'
usage.28=''
usage.29='  to place the legend center at (3 in, 7.8 in) from the left bottom corner '
usage.30='    lineplot -v ta.3 ta.1 -l "obs" "ERA40" -x 3 -y 7.8'
usage.31='  to place the lenged manually '
usage.32='    lineplot -v ta.3 ta.1 -l "obs" "ERA40" -p'
usage.33='  line plot only:'
usage.34='    lineplot -v ta.3 ta.1 -s 2'
usage.35='  legend only:'
usage.36='    lineplot -l "obs" "ERA40" -s 2'
usage.37='  draw legend vertically:'
usage.38='    lineplot -l "obs" "ERA40" -h 0'
usage.39=''
usage.40=''
*
**********************************************************************************
**********************************************************************************
***********************   STANDARDS   **************************************************
i=1
f=subwrd(args,i)
herr=0
xerr=0
yerr=0
nerr=0
terr=0
xx=0
yy=0
k=0
l=0
m=0
nl=0
nvar=0
placeit=0
drawHorizontal=1
ss=1
***********************   HELP   **************************************************
if (f='')
 i=0
 while (i<nusage)
   say usage.i
   i=i+1
 endwhile
 return
endif

***********************   OPTIIONS   **************************************************
while (f!='')
  opt = substr(f,2,1)
  if (opt='h' | opt='H' | opt='x' | opt='y' | opt='X' | opt='Y' | opt='s' | opt='S')
   i=i+1
   arg = subwrd(args,i)
   ttt = valnum(arg) 
#   say ttt
   if (ttt=0)
#   if (ttt='-' | ttt='')
# must be a value   
    i=i-1
    if (opt='h' | opt='H')
     herr=1
     say '-h error: direction not specified!'
     say '          draw horizontally.'
    endif
    if (opt='x' | opt='X')
     xerr=1
     say '-x error: X position missing!'
     say '          left side will be used.'
    endif
    if (opt='y' | opt='Y')
     yerr=1
     say '-y error: Y position missing!'
     say '          upper side will be used.'
    endif
#    if (opt='n' | opt='N')
#     nerr=1
#     say '-n error: number not specified!'
#     say '          take # of texts.'
#    endif
    if (opt='s' | opt='S')
     nerr=1
     say '-s error: symbol not specified!'
     say '          take 0 (GrADS default).'
    endif
   endif
   if ((opt='h' | opt='H') & herr=0); drawHorizontal=stripstr(arg); say drawHorizontal; endif;
   if ((opt='x' | opt='X') & xerr=0); xx=stripstr(arg); endif;
   if ((opt='y' | opt='Y') & yerr=0); yy=stripstr(arg); endif;
   if ((opt='s' | opt='S') & nerr=0); ss=stripstr(arg); endif;
  endif
  if (opt='p'); placeit=1; endif;
  if (opt='l' | opt='L')
   i=i+1
   arg = subwrd(args,i)
   ttt=substr(arg,1,1)
   ta=substr(arg,1,1)
   if (ttt != '')
     te=substr(arg,wrdlen(arg),1)
   endif
   if (ttt='-' | ttt='')
    terr=1
    say '-l error: text missing!'
    say '          Draw lines and symbols but no text.'
    return
   endif
   if (terr!=1)
    terr=2
    if (ta!='"')
      say '-l error: text must be double quoted!'
      say 'ABORT ! ! !'
      return
    endif
    while (ttt!='' & ttt!='-')
     nl=nl+1
     i=i+1
     texts.nl=stripstr(arg)
     while (te!='"')
      arg = subwrd(args,i)
      ttt=substr(arg,1,1)
      ta=substr(arg,1,1)
      if (ttt != '')
       te=substr(arg,wrdlen(arg),1)
      endif
      if (ttt='-' | ttt='')
        say '-l error: text must be quoted!'
        say 'ABORT ! ! !'
        return
      endif
      if (te='"') 
        arg=stripstr(arg)
      endif
      texts.nl=texts.nl%' '%arg
      i=i+1
     endwhile
     arg = subwrd(args,i)
     ttt=substr(arg,1,1)
     ta=substr(arg,1,1)
     if (ttt != '')
      te=substr(arg,wrdlen(arg),1)
     endif
    endwhile
    i=i-1
   endif
  endif
  if (opt='v' | opt='V')
    j=0
    i=i+1
    arg = subwrd(args,i)
    ttt=substr(arg,1,1)    
    while (ttt!=''&ttt!='-')
      var.j=arg
      j=j+1
      i=i+1
      arg = subwrd(args,i)
      ttt=substr(arg,1,1)    
    endwhile
    nvar=j
    if(nvar=0);say "no variable specified!";endif
#   roll back    
    i=i-1
  endif  
  i=i+1
  f=subwrd(args,i)
endwhile

***********************   GRADS STANDARDS   **************************************************
if (ss=0)
  _col.0=1;_col.1=3;_col.2=7;_col.3=3;_col.4=6;_col.5=9;_col.6=10;_col.7=11;_col.8=12;_col.9=15;
  _style.0=1;_style.1=1;_style.2=1;_style.3=1;_style.4=1;_style.5=1;_style.6=1;_style.7=1;_style.8=1;_style.9=1;
  _mark.0=2;_mark.1=3;_mark.2=4;_mark.3=5;_mark.4=1;_mark.5=2;_mark.6=3;_mark.7=4;_mark.8=5;_mark.9=1;
  _thick.0=6;_thick.1=6;_thick.2=6;_thick.3=6;_thick.4=6;_thick.5=6;_thick.6=6;_thick.7=6;_thick.8=6;_thick.9=6;
endif
***********************   My STANDARDS   **************************************************
if (ss=1)
  _col.0=1;_col.1=1;_col.2=3;_col.3=2;_col.4=4;_col.5=9;_col.6=8;_col.7=11;_col.8=12;_col.9=15
  _style.0=0;_style.1=1;_style.2=1;_style.3=2;_style.4=3;_style.5=4;_style.6=5;_style.7=6;_style.8=1;_style.9=1;
  _mark.0=2;_mark.1=0;_mark.2=0;_mark.3=0;_mark.4=0;_mark.5=0;_mark.6=0;_mark.7=0;_mark.8=0;_mark.9=0;
  _thick.0=1;_thick.1=3;_thick.2=12;_thick.3=6;_thick.4=6;_thick.5=6;_thick.6=6;_thick.7=6;_thick.8=6;_thick.9=6;
endif
if (ss=2)
  _col.0=1;_col.1=3;_col.2=2;_col.3=4;_col.4=9;_col.5=8;_col.6=11;_col.7=12;_col.8=15;_col.9=16
  _style.0=1;_style.1=1;_style.2=1;_style.3=1;_style.4=1;_style.5=1;_style.6=1;_style.7=1;_style.8=1;_style.9=1;
  _mark.0=2;_mark.1=3;_mark.2=4;_mark.3=5;_mark.4=1;_mark.5=2;_mark.6=3;_mark.7=4;_mark.8=5;_mark.9=1;
  _thick.0=6;_thick.1=6;_thick.2=6;_thick.3=6;_thick.4=6;_thick.5=6;_thick.6=6;_thick.7=6;_thick.8=6;_thick.9=6;
endif
***********************   CONSISTENCY   **************************************************
#if (nn=0 & nl=0 & nvar=0)
#   say 'nothing specified!'
##   return
#endif
#nl=max(nn,nl)
#nl=nn
#if(nl>nl);nl=nl;endif
#if (nn!=0 & nn!=nl)
#   if (nn>nl)
#     say '# of lines greater # of texts'
#     say 'Rest will be lines with empty strings'
#   else
#     say '# of lines lower # of texts'
#     say 'discard # of lines; take # of texts'
#   endif
#endif
#if (nl>10)
#  say '# limit to 10'
#  say 'discard the rest'
#  nl=10
#endif

***********************   lineplot  **************************************************
i=0
vstring=""
while(i<nvar)
  vstring=vstring" "var.i
  i=i+1
endwhile
if(nvar>0);plot(vstring);endif
***********************   FILL TEXT   **************************************************
p=0 
while (p<nl)
  p=p+1
  if (p>nl); texts.p=''; endif
endwhile

***********************   GRAPHICS   **************************************************
'query gxinfo'
****** example: rec2 =>   Page Size = 11 by 8.5
rec2 = sublin(result,2)
******          rec3 =>   X Limits = 1.3 to 10.2
rec3 = sublin(result,3)
******          rec4 =>   Y Limits = 1.58 to 6.92
rec4 = sublin(result,4)

xsiz = subwrd(rec2,4)
ysiz = subwrd(rec2,6)
yhi = subwrd(rec4,6)
ylo = subwrd(rec4,4)
xhi = subwrd(rec3,6)
xlo = subwrd(rec3,4)
xd = xsiz - xhi
yd = ysiz - ylo
xwid = xsiz/20
ywid=yd/20

if (xx=0); xx=(xlo+xhi)/2; endif;
if (yy=0)
  if (drawHorizontal=1)
    yy=ylo
  else
    yy=ylo+ywid*nl
  endif
endif;
#if (yy=0); yy=yhi; endif;
if (placeit=1)
  say ''
  say 'Click where you want the left upper corner of the legend'
  'query bpos'
  x = subwrd(result,3)
  y = subwrd(result,4)
  say 'Print legend at X Y: 'x' 'y
  xx=x
  yy=y
endif


xl=xx

xr=xl+xwid
y=yy
y=y+ywid

'set strsiz 0.12 0.13'

***********************   DRAW LEGEND   **************************************************
* calculate the legend length
o=0
length=0
while (o<nl)
  old=o
  o=o+1
  if (drawHorizontal=1)
#    length=length+0.1+0.12*(math_strlen(texts.old)+2)
    length=length+xwid+0.12*(math_strlen(texts.old)+2)
  endif
endwhile
if (length>(xhi-xlo))
  length=(xhi-xlo)
endif
o=0
while (o<nl)
  old=o
  o=o+1
  if (drawHorizontal=1)
    if (o=1)
      xl=xx-length/2
    else
#      xl=xr+0.1+0.12*(math_strlen(texts.old)+2)
      xl=xl+xwid+0.12*(math_strlen(texts.old)+2)
      xrr=xl+xwid+0.12*(math_strlen(texts.o))
      if (xrr>xhi) 
#       change new line
        xl=xx-length/2
        y=y+ywid 
      endif
    endif
    xr=xl+xwid
  else
    y=y-ywid
  endif
  if(_style.old!=0)
    'set line '_col.old' '_style.old' '_thick.old
    'draw mark '_mark.old' 'xl' 'y' 0.1'
    'draw line 'xl' 'y' 'xr' 'y
    'draw mark '_mark.old' 'xr' 'y' 0.1'
  else
    x=(xl+xr)/2.
    'set line '_col.old' '_style.old' '_thick.old
    'draw mark '_mark.old' 'x' 'y' 0.1'
  endif
  'set string 1 l 5'
  if (texts.o!='')
    'draw string '%(xr+0.1)%' 'y' 'texts.o
  endif
endwhile


return
#exit
***********************   END   **************************************************
**********************************************************************************
**********************************************************************************
**********************************************************************************


function plot(args)
# say "plot " args
* Get arguments
if (args='?')
  say 'usage: plot v1 v2 ... vn'
  say 'v1 = variable 1'
  say 'v2 = variable 2'
  say 'vn = variable n'
  return
else
  i=0
  i1=i+1
  var.i=subwrd(args,i1)
  while (var.i!='')
    i=i+1
    i1=i+1
    var.i=subwrd(args,i1)
  endwhile
  nvar=i
endif


# Find vrange
  'set gxout stat'
  i=0
  while (i<nvar)
    'd 'var.i
    line8=sublin(result,8)
    localMin=subwrd(line8,4)
    localMax=subwrd(line8,5)    
    if(i=0)
      rangeMin=localMin
      rangeMax=localMax
    else
      if(localMin<rangeMin);rangeMin=localMin;endif
      if(localMax>rangeMax);rangeMax=localMax;endif
    endif
    i=i+1
  endwhile
  if((rangeMax-rangeMin)>0)
    mul=1
    while((rangeMax-rangeMin)<mul)
      mul=mul/10
    endwhile
#    say "mul="mul
    rangeMin=math_int(rangeMin/mul)*mul
    rangeMax=math_int(rangeMax/mul+1)*mul
    scale=math_log10(rangeMax-rangeMin)/4
    scale=math_pow(10,-math_int(scale))
    if(scale!=0);scale=math_int((rangeMax-rangeMin)/4*scale)/scale;else;scale=math_int((rangeMax-rangeMin)/4);endif
    rangeMin=rangeMin-scale
#    say 'set vrange 'rangeMin' 'rangeMax
    'set vrange 'rangeMin' 'rangeMax
    'set ylint 'scale
  else
   say var.i' undefined'
  endif  
#  exit
  'set grads off'
#  'set datawarn off' 
#  'set tlsupp year'
#  'set 'axis' 'start' 'end
  'set gxout line'
  i=0
  while (i<nvar)
    'set ccolor '_col.i
    'set cstyle '_style.i 
    'set cmark '_mark.i
    'set cthick '_thick.i
    'd 'var.i
    i=i+1
  endwhile  
  
return
#exit  





*************************   MAXIMUM NUMBER   *************************************************
function max(wert1, wert2)
* liefert die groessere von zwei Zahlen
if (wert1 <= wert2)
 return (wert2)
else
 return (wert1)
endif
return

*************************   LENGTH OF WORD   *************************************************
function wrdlen (arg)
i=1
s=subwrd(arg,1)
if (s='') 
 return 0
else
 t=substr(s,i,i)
 while (t!='')
  i=i+1
  t=substr(s,i,i)
 endwhile 
endif

return (i-1)


*************************   STRIP STRING OF DOUBLE QUOTES  *************************************************
function stripstr (arg)

i=1
len=0
s=subwrd(arg,i)
if (s='') 
 return 0
else
 a=substr(s,1,1)
 if (a='"')
  s=substr(s,2,wrdlen(s))
 endif
 e=substr(s,wrdlen(s),1)
 if (e='"')
  s=substr(s,1,wrdlen(s)-1)
 endif
endif

return s